/*
 * 2023/03/14 T.Wanibe 
 * DHCP Chat  Server
 * 着信メッセージを接続されているすべてのクライアントに配信する単純なサーバー。 
 * デバイスの IP アドレスとタイプに telnet を使用するには。
 * シリアル モニターでもクライアントの入力を確認できます。
 * W5500-EVB-PICOを使用します。
 * このバージョンは、DHCP を使用して IP アドレスを取得しようとします
 * 最大1044480バイトのフラッシュメモリのうち、スケッチが62484バイト（5%）を使っています。
 * 最大262144バイトのRAMのうち、グローバル変数が7996バイト（3%）を使っていて、ローカル変数で254148バイト使うことができます。
 */
#include        <SPI.h>
#include        <Ethernet3.h>
#define         SPI_SCK         18
#define         SPI_RX          16
#define         SPI_TX          19
#define         SPI_CS          17
#define         NICReset        20
#define         HTTPport        80
#define         TELNETport      23
#define         SerialRate      115200
// コントローラの MAC アドレスと IP アドレスを以下に入力します。
// IP アドレスは、ローカル ネットワークによって異なります。
// ゲートウェイとサブネットはオプションです。
byte            mac[]           = {0x00,0x08,0xDC,0x54,0x4D,0xE0};              //WIZNET
byte            ip[]            = {192, 168, 0, 210};
byte            dns_server[]    = {192, 168, 0, 1};
byte            gateway[]       = {0, 0, 0, 0};
byte            subnet[]        = {255, 255, 255, 0};
boolean         gotAMessage     = false;                                        // クライアントからのメッセージをまだ受け取っているかどうか
// telnet のデフォルトはポート 23 です
EthernetServer  server(TELNETport);
//----------------
void setup() {
        // シリアル通信を開きます。
        Serial.begin(SerialRate);
        while (!Serial) {
                ;                               // シリアルポートが接続されるのを待ちます。
        }
        // イーサネット接続を開始します。
        pinMode(SPI_CS,OUTPUT);
        pinMode(NICReset,OUTPUT);
        // イーサネット接続とサーバーを開始します。
        SPI.setSCK(SPI_SCK);
        SPI.setRX(SPI_RX);
        SPI.setTX(SPI_TX);
        SPI.setCS(SPI_CS);
        SPI.begin();
        // Ethernet.init（pin）を使用してCSピンを設定できます
        Ethernet.setCsPin(SPI_CS);
        Ethernet.setRstPin(NICReset);
        digitalWrite(NICReset,LOW);
        delay(10);
        digitalWrite(NICReset,HIGH);
        Ethernet.init(SPI_CS);
        Serial.println("Trying to get an IP address using DHCP");
        if (Ethernet.begin(mac) == 0) {
                Serial.println("Failed to configure Ethernet using DHCP");
                // DHCP を使用せずにイーサネット デバイスを初期化します。
                Ethernet.begin(mac, ip, subnet, gateway);
        }
        // ローカル IP アドレスを印刷します。
        Serial.print("My IP address: ");
        Serial.println(Ethernet.localIP());
        Serial.println();
        // クライアントのリスニングを開始する
        server.begin();
}
//----------------
void loop() {
        // 新しいクライアントを待ちます:
        EthernetClient client = server.available();
        // クライアントが最初のバイトを送信したら、こんにちはと言ってください:
        if (client) {
                if (!gotAMessage) {
                        Serial.println("We have a new client");
                        client.println("Hello, client!");
                        gotAMessage = true;
                }
                // クライアントから受信したバイトを読み取ります。
                char thisChar = client.read();
                // バイトをクライアントにエコー バックします。
                server.write(thisChar);
                // バイトをサーバーにもエコーします。
                Serial.print(thisChar);
        }
}