/*
* 2020/10/1 T.Wanibe
* PWM対応のPCFANを制御するプログラムを検討する
* PB10:Sencer入力
* PB0:PWM出力
* LED&KEYを接続して回転数とDUTY比を表示する
* DUTY比はA0に接続したポテンショメータで変動させる
* たまきちさんのライブラリを採用したためPWMのDUTYは0-4095の入力であり、直接ADC値を割り当てています。
* 最大131072バイトのフラッシュメモリのうち、スケッチが38160バイト（29%）を使っています。
* 最大20480バイトのRAMのうち、グローバル変数が4376バイト（21%）を使っていて、ローカル変数で16104バイト使うことができます。
*/
#include <TM1638.h>
#include <libmaple/timer.h>
#define TIMER_DIV 72
#define dataPin PB4
#define clockPin PB3
#define strobePin PA15
#define LED1_Pin PB8
#define LED2_Pin PB9
#define CI_Pin PB10 //senserPulse入力pin
#define PWM_Pin PB0 //25KhzPWM出力
#define DUTY_PIN PA0 //DUTY制御用入力 0−4095
#define pFreq1 25000 //出力パルス周波数(0 〜 65535)
//#define pDuty1 2047 //デューティ比 (0〜 4095:4095で100%)
#define SerialValid false
volatile bool CntValid = false;
volatile long gCountValue = 0;
volatile long gViewValue = 0;
uint32 preTime,postTime;
char buf[20];
float gRpm;
int gDuty = 2047; //50%duty
// define a module on data pin PB4, clock pin PB3 and strobe pin PA15
TM1638 LEDandKEY(dataPin, clockPin, strobePin);
//------------------信号変化割込でカウンタ値をインクリメントする。
void CountUp(void) {
postTime = micros();
digitalWrite(LED2_Pin,HIGH);
uint32 interval = postTime - preTime; //1回転に2パルス
preTime = postTime;
gRpm = 30000 /interval; //usecInterval をRPMに換算
if(SerialValid) Serial.print(F("*"));
gCountValue++;
digitalWrite(LED2_Pin,LOW);
}
//---------------
void ViewValue(void){ //表示更新は個々にせず定期的に実施する
float vDuty = gDuty /4.095; //小数点位置は固定表示
if(gRpm > 20000){
sprintf(buf,"----%4.0f",vDuty);
LEDandKEY.setDisplayToString(buf,2,0);
}else{
sprintf(buf,"%4.0f%4.0f",gRpm,vDuty);
LEDandKEY.setDisplayToString(buf,2,0);
}
CntValid = true;
}
uint8_t pwm1_out(uint8_t pin, uint16_t freq, uint16_t duty) {
/*
* このコードはたま吉さんによる周波数を指定したPWM実現関数です。感謝
* https://nuneno.cocolog-nifty.com/blog/2017/04/index.html
* PWM出力
* 引数
* pin PWM出力ピン
* freq 出力パルス周波数(0 〜 65535)
* dcycle デューティ比 (0〜 4095:4095で100%)
* 戻り値
* 0 正常
* 1 異常(PWMを利用出来ないピンを利用した)
*/
uint32_t dc;
timer_dev *dev = PIN_MAP[pin].timer_device; // ピン対応のタイマーデバイスの取得
uint8_t cc_channel = PIN_MAP[pin].timer_channel; // ピン対応のタイマーチャンネルの取得
if (! (dev && cc_channel) ) return 1;
uint32_t f =1000000/(uint32_t)freq; // 周波数をカウント値に換算
dc = f*(uint32_t)duty/4095;
timer_set_prescaler(dev, TIMER_DIV); // システムクロックを1MHzに分周
timer_set_reload(dev, f); // リセットカウント値を設定
timer_set_mode(dev, cc_channel,TIMER_PWM);
timer_set_compare(dev,cc_channel,dc); // 比較レジスタの初期値指定(デューティ比 0)
return 0;
}
//---------------
void setup() {
if(SerialValid) Serial.begin(115200);
if(SerialValid) Serial.println(F("Start"));
//LED&KEYに０を表示
LEDandKEY.setDisplayToString(" 0 0",0,0);
//PINMODE設定
pinMode(LED1_Pin, OUTPUT); //LED出力設定
pinMode(LED2_Pin, OUTPUT);
pinMode(CI_Pin, INPUT_PULLUP); //カウンタ入力Pin設定
pinMode(PWM_Pin, PWM); //パルス出力1
pinMode(DUTY_PIN, INPUT_ANALOG); //アナログ入力
//
Timer1.pause(); //念のためタイマ停止
Timer1.setPrescaleFactor(7200); //システムクロック 72MHzを分周して100uSECにセット
Timer1.setOverflow(5000); //オーバーフローを1SECに設定 U16
Timer1.attachInterrupt(TIMER_UPDATE_INTERRUPT,ViewValue);
attachInterrupt(CI_Pin,CountUp,RISING); //RISING,FALLING,CHANGE
Timer1.setCount(0); //カウンタを0に設定
Timer1.refresh();
Timer1.resume();
pwmWrite(PWM_Pin, 0); //設定直後に出力を止める
pwm1_out(PWM_Pin,pFreq1,gDuty); //duty50% 32767/65535
}
//------------------
int LoopCount = 0;
void loop() {
if(CntValid){
//表示処理は割込で行うとパルスの取りこぼしが発生しやすい
//ledでタイミング表示していますが、この処理で遅れが出ます。
if(++LoopCount % 2){
digitalWrite(LED1_Pin,HIGH);
//digitalWrite(LED2_Pin,LOW);
}else{
digitalWrite(LED1_Pin,LOW);
//digitalWrite(LED2_Pin,HIGH);
}
gViewValue = 0;
CntValid = false;
}
gDuty = analogRead(DUTY_PIN);
pwm1_out(PWM_Pin,pFreq1,gDuty);
}
